Skip to main content

Elixir - destructuring, function overloading and pattern matching

Why am I covering 3 Elixir topics at once? Well, perhaps it is to show you how the three are used together.

Individually, any of these 3 are interesting, but combined, they provide you with a means of essentially getting rid of conditionals and spaghetti logic.

Consider the following function.


  def greet_beatle(person) do
    case person.first_name do
      "John" -> "Hello John."
      "Paul" -> "Good day Paul."
      "George" -> "Georgie boy, how you doing?"
      "Ringo" -> "What a drummer!"
      _-> "You are not a Beatle, #{person.first_name}"
    end
  end

Yeah, it basically works, but there is a big old case statement in there. If you wanted to do something more as well depending on the person, you could easily end up with some spaghetti logic. Let's see how we can simplify this a little.

  def greet_beatle(%{first_name: first_name}) do
    case first_name do
      "John" -> "Hello John."
      "Paul" -> "Good day Paul."
      "George" -> "Georgie boy, how you doing?"
      "Ringo" -> "What a drummer!"
      _-> "You are not a Beatle, #{first_name}"
    end

  end

First thing we did was destructuring. We took the person map and took out the first_name. Not so much of a big deal at first, but this allows us to do something really neat in the next instance.

But first I will digress. In Elixir, you can actually define a function multiple times with the same name. It can use the arity (number of arguments) to determine which function to run. For example:

  def full_name(first_name, last_name) do
    "#{first_name} #{last_name}"
  end
  
  def full_name(first_name, middle_name, last_name) do
    "#{first_name} #{middle_name} #{last_name}"
  end

When you call full_name("John", "Smith") the first function will run and you get "John Smith". When you call full_name("John", "Edgar", "Smith") the second function will run and you will get "John Edgar Smith".

However, more than that, you can combine function overloading with pattern matching. This gives you some more options. Let's combine these features into our example.


  def greet_beatle(%{first_name: "John"}) do
    "Hello John."
  end
  
  def greet_beatle(%{first_name: "Paul"}) do
    "Good day Paul."
  end
  
  def greet_beatle(%{first_name: "George"}) do
    "Georgie boy, how you doing?"
  end
  
  def greet_beatle(%{first_name: "Ringo"}) do
    "What a drummer!"
  end
  
  def greet_beatle(%{first_name: first_name}) do
    "You are not a Beatle, #{first_name}"
  end

So as you can see, we can completely eliminate our case statement from earlier (and case is basically a conditional). This allows us to have a flatter hierarchy and makes the code easier to read.

The other advantage is that this can provide more robust error handling. Let's say the map you are passing in does not even have a first_name. In the first version of the code, this would give you an error. You can now add another function handler at the bottom.


  def greet_beatle(_) do
    "I'm sorry, I did not get your name"
  end
We will first run through the first 5 definitions which pattern match on the first_name attribute. If there is no first_name attribute, then we will move to the next definition. In this case I used the _ which is a pattern matching catch all.

The other thing we get from destructuring is it helps us deal with highly nested data structures. Let's say that a Person, on top of having a first and last name, has an address (which may or may not be null) and that address has a street which you want to use in the greeting.

e.g.


  def greet(person) do
    case person.address do
      nil -> "Hello #{person.first_name}"
      address -> "Hello #{person.first_name} from #{person.address.street} street."   
    end
  end

The above code will work, but is a little messy and hard to read. Not only that but person.address.street breaks the Law of Demeter

Consider instead the following


  def greet(%{first_name: first_name, address: %{street: street}}) do
    "Hello #{first_name} from #{street} street."
  end
  
  def greet(%{first_name: first_name}) do
    "Hello #{first_name}"
  end
Destructuring and pattern matching helps us with the law of Demeter and also makes the code flatter.

If you come from Ruby, the above code might seem a little backwards at first. I admit that I sometimes still write my functions initially by passing in the whole map and I tend to destructure once I have worked out the logic inside. Always remember that the first time you write a function is not necessarily how it will look in the end though and I always look for pattern matching and destructuring opportunities in code I have already written.

Comments

Popular posts from this blog

Freezing Gems

What is a gem and why would you want to freeze it?

In Ruby, there are times when you want to access pieces of functionality that other people of written (3rd party libraries) and you normally have 2 options. You can install a plug in or install a gem. Normally the method you use is determined by which ever is made available by the author.

Gems are installed on the host machine and are pretty handy when you want to run things in the command line or else across lots of projects, but their downside is that if you use a gem in a Rails project there is no automatic publishing mechanism when you deploy your site. You will need to log onto the remote host machine and install the gem manually.

Plugins are specific to Rails and are similar to gems in that they are also 3rd party libraries. However they are associated with your Rails project as opposed to your machine so they will get posted to the server on a regular deploy.

Freezing a gem is the process of transforming a gem into a plug in. Essen…

Unit/Functional Testing RubyAMF

One of my current projects is using RubyAMF to communicate with Flash (http://rubyforge.org/projects/rubyamf/). On the whole this is really nice because it allows you to transfer Ruby objects directly to ActionScript ones (as opposed to translating the object into XML, sending the XML and then recreating the object in ActionScript).
However, Rails does not provide a built in transport mechanism for AMF, so we cannot run functional testing directly on the data call (as we could for an XML or HTML transport layer). This is a show stopper for a lot of people (Rails w/o Unit testing = a big mess of trouble when something goes wrong).
We can though serve both the HTML and the AMF formats depending on the request format. This means that we can test the object instantiation logic and make sure there are no errors in the controllers (though we cannot check the actual format of the data being served). In the controller, instead of rendering AMF alone, do the following respond_to do |format|

Comparing Rails' Active Record Pattern with Phoenix/Elixir/Ecto

Rails has a very well established Active Record pattern for dealing with the database. You have an Active Record model which maps to the database table, the schema of the model comes directly from the database schema and you place your model specific methods on the Active Record model. This file is also where you set your model relationships (e.g. has_many, has_one, belongs_to). Your instance of the model has all the methods built in.

In Ecto/Phoenix it's a little different. First of all, the database schema doesn't automatically map to the "model". In fact we don't really have models (as Elixir is a functional paradigm). What happens in one file in Rails, happens in essentially two (or more). You have a schema file (where you have to list out all the attributes and relationships). Using the schema file, your "instance" is essentially a data structure (with no methods on it). If you want to transform the data on your struct, you would use a context modu…